تبديل اتصال واجهات الميكروتك – الانترفيس – في حالة وجو مزود خدمة انترنت واحد بنفس ip

اخر تحديث في مايو 27, 2023 بواسطة حمدي بانجار

تبديل اتصال واجهات الميكروتك – الانترفيس – في حالة وجو مزود خدمة انترنت واحد بنفس ip

في ما يلي سكربت يقوم بتبديل الاتصال بين واجهات اثنين (عادةً wan).

مثال: لقد وفر ISP x اتصالاً عبر الإنترنت عبر رابط الألياف. كوصلة لـ backup / redundancy قام مزود خدمة الإنترنت بتوفير خط الألياف الثاني.

كلا الرابطين لهما نفس عنوان IP مع نفس البوابة.

هناك طرق أخرى أيضًا ، هذه مجرد طريقة واحدة لتحقيق المهمة.

يمكن تخصيصها بعدة طرق مثل فرض مراقبة مضيف معين بواسطة ping والتصرف وفقًا لذلك ، أو عن طريق وجود بريدج وما إلى ذلك.

مثال عنوان IP:

في /ip address >>>

sfp1 = 10.0.0.1 (مع كتابة تعليق “PRIMARY-SFP1”)
[يظل ممكنا حتى تتغير الحالة التالية]

sfp2 = 10.0.0.1 (مع كتابة تعليق “SECONDARY-SFP2”)
[يظل ممكنا حتى تتغير الحالة التالية]

السكربت سوف يفعل ما يلي :

سيتحقق من حالة SFP1 ، إذا لم يتم العثور على رد “link – ok” ، فسوف يسجل الحدث ، ويرسل تنبيهًا عبر البريد الإلكتروني / الرسائل القصيرة إلى المسؤول ، وسقوم بالتبديل إلى منفذ SFP2 من خلال تمكين بروتوكول IP الخاص بـ SFP2 [وتعطيل بروتوكول IP على SFP1]

على المدى التالي :

إذا وجد ان رابط SFP1 عاد للعمل ، فسيقوم بتسجيل الحدث وإرسال تنبيه عبر البريد الإلكتروني / الرسائل القصيرة إلى المسؤول ، والرجوع مرة أخرى إلى منفذ SFP1 عن طريق تمكين IP من SFP1 وتعطيل ip على SFP2.

# Mikrotik SPF Link monitoring SCRIPT with optional Email and SMS Alert,
# We are using local KANNEL as SMS gateway and GMAIL as email sender
# by Syed Jahanzaib
# https://aacable.wordpress.com
# Email : aacable at hotmail dot com
# Script Last Modified : 25-NOV-2016 / 1400 hours
 
# PRIMARY FIBER LINK
:local INT "sfp1"
# SECONDARY BACKUP FIBER LINK
:local INT2 "sfp2"
:local i 0;
:local F 0;
:local date;
:local time;
:global sub1 ([/system identity get name])
:global sub2 ([/system clock get time])
:global sub3 ([/system clock get date])
:set date [/system clock get date];
:set time [/system clock get time];
:local cell1 "03333021909"
:global FIBERnetstatus;
:global FIBERnetlastchange;
:global FIBERIP;
 
# Company Name, do not use spaces in it
:local COMPANY "ZZZ"
 
# Setting GMAIL config
:local sub1 ([/system identity get name])
:local sub2 ([/system clock get date])
:local sub3 ([/system clock get time])
:local TO1 "[email protected]"
:local gmailid "[email protected]"
 
#If you dont have kannel sms gateway ignore this.
:local KURL "http://10.0.0.1:13013/cgi-bin/sendsms"
:local KID "kannel"
:local KPASS "KANNEL-PASS"
 
# SMS DOWN status Msg format for Kannel SMS gateway (donot use spaces in it)
:local MSGDOWNSMS "$COMPANY+FIBER+ALERT:%0A$INT+fiber+is+now+DOWN.%0ASwitching+to+$INT2+backup+fiber+link"
# SMS UP status Msg format for Kannel SMS gateway (donot use spaces in it)
:local MSGUPSMS "$COMPANY+FIBER+INFO:%0A$INT+fiber+is+now+UP.%0ASwitching+back+to+$INT"
 
# EMAIL Msg format for FIBER DOWN
:local MSGDOWNEMAIL "$COMPANY FIBER ALERT: $INT fiber is now DOWN at $sub1 $sub2 $sub3 . Switching to $INT2 backup link. Please Verify it."
# EMAIL Msg format for FIBER UP
:local MSGUPEMAIL "$COMPANY FIBER INFO: $INT fiber is now UP at $sub1 $sub2 $sub3 . Switching back to $INT primary link. Please Verify it."
# LOG error
:local DOWNLOG1 "$COMPANY FIBER ALERT: $INT fiber is now DOWN at $sub1 $sub2 $sub3 . Switching to $INT2 backup link. Please Verify it."
:local UPLOG1 "$COMPANY FIBER INFO: $INT fiber is now UP at $sub1 $sub2 $sub3 . Switching back to $INT primary link. Please Verify it"
 
######################################
########## Start the SCRIPT ###############
########## DONOT EDIT BELOW ############
######################################
 
local link;
/interface ethernet cable-test $INT once do={
:set link $"status";
};
 
:if ($link != "link-ok") do={
:log error "$INT SFP DOWN"
 
:if (($FIBERnetstatus="UP")) do={
:set FIBERnetstatus "DOWN";
 
# Also add status in global variables to be used as tracking
:set date [/system clock get date];
:set time [/system clock get time];
:set FIBERnetlastchange ($time . " " . $date);
##################################################
####### FOR DOWN STATUS, CHANGE THE RULES ########
##################################################
 
# If the link is down, then LOG info and warning in Mikrotik LOG window [Zaib]
:log error "$DOWNLOG1"
 
# DOWN ACTION , shifting to SFP2 , backup link
/ip address set disabled=yes [find comment="PRIMARY-SFP1"]
/ip address set disabled=no [find comment="BACKUP-SFP2"]
 
# Adding delay so gateway should be reachable properly
:delay 5s;
 
:global gmailsmtp
:set gmailsmtp [:resolve "smtp.gmail.com"];
 
# "Emailing the DOWN status. . . "
/tool e-mail send to=$TO1 subject="$MSGDOWNEMAIL" start-tls=yes body="$MSGDOWNEMAIL"
 
# Send SMS the DOWN status via KANNEL
/tool fetch url="$KURL\?username=$KID&password=$KPASS&to=$cell1&text=$MSGDOWNSMS"
 
##################################################
####### FOR UP STATUS, CHANGE THE RULES ########
##################################################
 
} else={:set FIBERnetstatus "DOWN";}
} else={
:if (($FIBERnetstatus="DOWN")) do={
 
:set FIBERnetstatus "UP";
 
# If link is UP, then LOG info and warning in Mikrotik LOG window [Zaib]
:log warning "$UPLOG1"
 
# UP ACTION , shifting back to SFP1
/ip address set disabled=no [find comment="PRIMARY-SFP1"]
/ip address set disabled=yes [find comment="BACKUP-SFP2"]
 
# Adding delay so gateway should be reachable properly
:delay 5s;
:global gmailsmtp
:set gmailsmtp [:resolve "smtp.gmail.com"];
 
# "Emailing the UP status. . . "
/tool e-mail send to=$TO1 subject="$MSGUPEMAIL" start-tls=yes body="$MSGUPEMAIL"
 
# Send SMS via KANNEL Gateway
/tool fetch url="$KURL\?username=$KID&password=$KPASS&to=$cell1&text=$MSGUPSMS"
 
:set date [/system clock get date];
:set time [/system clock get time];
:set FIBERnetlastchange ($time . " " . $date);
 
} else={:set FIBERnetstatus "UP";}
}

انتهى … تبديل اتصال واجهات الميكروتك – الانترفيس – في حالة وجو مزود خدمة انترنت واحد بنفس ip

تبديل اتصال واجهات الميكروتك – الانترفيس – في حالة وجو مزود خدمة انترنت واحد بنفس ip

ملاحظة :

قد تكون المقالة محمية ضد النقل وبالتالي لنسخ الاكواد ان وجدت انقر على علامة + بأعلى يمين الكود والتي تظهر عند تمرير الماوس على الكود .

الى هنا نكون وصلنا الى نهاية موضوعنا اليوم :

تبديل اتصال واجهات الميكروتك – الانترفيس – في حالة وجو مزود خدمة انترنت واحد بنفس ip

والذي نتمنى ان ينال رضاكم واعجابكم والى اللقاء في موضوع جديد شيق ورائع

وحتى ذلك الحين لاتنسو الاهتمام بصحتكم وحفظكم الله …

اذا اعجبك الموضوع تبديل اتصال واجهات الميكروتك – الانترفيس – في حالة وجو مزود خدمة انترنت واحد بنفس ip لاتبخل علينا بمشاركتة على مواقع التواصل الاجتماعي ليستفيذ منه الغير,

كما نتمنى اشتراككم في قناة الموقع على اليوتيوب بالضغط هنا وكذلك الاشتراك في مجموعة الفيس بوك بالضغط هنا والتيليقرام بالضغط هنا  وكذلك التسجيل بالموقع لتتمكنو من تحميل بعض الملفات الخاصة بالأعضاء

كما يمكنكم رفع ملفاتكم مجانا على مركز ملفات حضرموت التقنية بالضغط هنا ولاتترددو في وضع أي استفسارات للرد عليكم .

دمتم بكل ود والسلام عليكم ورحمة الله وبركاتة  … حضرموت التقنية

حول حمدي بانجار

باحث ومهندس في مجالات شبكات ومقاهي الأنترنت - شغوف في عالم الانترنت والبرمجة للشبكات - في حضرموت التقنية شعارنا الدائم - أفعل الخير مهما أستصغرتة ! فأنك لاتدري اي عمل يدخلك الجنة ... فلا يفلح كاتم العلم ...طموحاتي ان يصبح الموقع مدرسة تعليمية للعلوم التقنية الجديدة ومساعدة الاخرين في حل مشكلاتهم ونرحب بمن يرغب الانظمام لنا يفيذ ويستفيذ ليكبر هذا الصرح التعليمي ويحقق الاستفاذة القصوى للغير ... أنظمامكم لأسرة الموقع وقناتها ومشاركتكم بالمواضيع الهادفه هو بحد ذاتة تشجيع لنا وللغير لاستمرارية هذا الصرح التعليمي

تحقق أيضا

Tools/Bandwidth Test ادوات اختبار الباندوث في سيرفر الميكروتك

Tools/Bandwidth Test ادوات اختبار الباندوث في سيرفر الميكروتك

اخر تحديث في مايو 27, 2023 بواسطة حمدي بانجار Tools/Bandwidth Test ادوات اختبار الباندوث في …